Some further recommendations and notes:

1. You do not need to use the Processor and list p = directives - the processor model should be selected in MPLAB before build, and thus will be passed to assembler via command line.

2. All SFRs are already defined in the processor include file, so you should never try to define them yourself.

3. At the very beginning of your code place the radix dec directive, and then use the human readable decimal numbers in their native form wherever possible.

4. Do not use multiple representation formats for hex numbers, i.e. H'ABCD' and 0ABCDh. There is a most common hex number representation format used in most programming languages - 0xABCD, so use only this one.

5. Learn and use the relocatable type of code generating. It's much more flexible and convenient than an old style absolute code type.

6. Make your routines reusable and flexible by passing the parameters to them instead of e.g. writing several delay routines with fixed parameters for every delay value required.

7. Do not calculate the numerical values manually, let the assembler do it automatically for you.

8. Try to avoid using numerical values unless it's absolutely necessary - use #define/equ to assign the numerical values to the named constants and use these named constants instead of "magic numbers".

9. Place a colon sign (:) after a label.

10. Comment your code, make the label and variable names self explanatory.

11. Put a whitespace between a semicolon and a comment text - ; Comment, not ;Comment.

12. Use tabulation instead of whitespace(s) to separate the command fields.

13. Separate functionally completed code blocks with empty lines.

14. Put labels at the beginning of SEPARATE lines, write commands and directives after tabulation.

15. Define an interrupt vector location and GOTO command even if you're not using interrupts yet - you will need them soon or later.

Here is an example of your code modified according to the above recommendations:

 
 ;-------------------------------------------------------------------------------------- 
 ;      LED LOOP TEST PROGRAM 
 ;-------------------------------------------------------------------------------------- 
         RADIX   dec                     ; Set native decimal numbers representation 
 #include        <p16F877A.INC>          ; CPU specific definitions 
 
 ;-------------------------------------------------------------------------------------- 
 ; Define named constants and assign values to them: 
 
 fosc            EQU     5000000         ; Crystal frequency, Hz 
 fcpu            EQU     fosc/4          ; CPU clock frequency, Hz 
 
 clks_1ms        EQU     fcpu/1000       ; Number of CPU clock cycles per 1 ms (1000 Hz) 
 
 tledon          EQU     50              ; Time to keep a LED on, ms (1..255 range) 
 tledoff         EQU     250             ; Time to keep a LED off, ms (1..255 range) 
 
 LED1            EQU     2               ; LED1 is connected to this port pin 
 
 ;-------------------------------------------------------------------------------------- 
 ; Initialize the nonvolatile configuration register(s): 
 
         __CONFIG        _XT_OSC & _WDT_OFF & _LVP_OFF & _CP_OFF 
 
 ;-------------------------------------------------------------------------------------- 
 ; Start a data section and declare register file variables here: 
 
         UDATA                           ; Unitialized data section directive 
 
 ; RES N directive reserves N bytes in a register file for variable(s): 
 
 mscnt:  RES     1                       ; Milliseconds counter for DELAY_MS routine 
 intcnt: RES     1                       ; Internal loop counter for DELAY_MS routine 
 ;-------------------------------------------------------------------------------------- 
 
 ;-------------------------------------------------------------------------------------- 
 ; Code sections follow: 
 
 ;-------------------------------------------------------------------------------------- 
 ; Reset vector - code gets executed from here after a reset. 
 
 reset   CODE    0 
         goto    start 
 ;-------------------------------------------------------------------------------------- 
 
 ;-------------------------------------------------------------------------------------- 
 ; Interrupt vector - in-place (no GOTO) interrupt service routine (stub) code. 
 
 isr     CODE    4 
         retfie 
 ;-------------------------------------------------------------------------------------- 
 
 ;-------------------------------------------------------------------------------------- 
 ; We get here from a Reset vector. 
 
 start: 
         BANKSEL ADCON1                  ; Switch to an ADCON1 and TRISA bank 
         movlw   6                       ; Configure PORTA for digital i/o 
         movwf   ADCON1                  ; 
 
         bcf     TRISA,LED1              ; Configure a LED pin as output 
         BANKSEL PORTA                   ; Switch to a PORTA bank 
 
 
 ;-------------------------------------------------------------------------------------- 
 ; Main program loop: 
 
 main: 
         bsf     PORTA,LED1              ; Turn a LED on for TLEDON ms 
         movlw   tledon                  ; 
         call    delay_ms                ; 
 
         bcf     PORTA,LED1              ; Turn a LED off for TLEDOFF ms 
         movlw   tledoff                 ; 
         call    delay_ms                ; 
 
         goto    main                    ; Loop 
 ;-------------------------------------------------------------------------------------- 
 
 ;-------------------------------------------------------------------------------------- 
 ; Subroutines. 
 
 ;-------------------------------------------------------------------------------------- 
 ; Delay for W milliseconds (W = 1..255 on entry): 
 
 delay_ms: 
         movwf   mscnt           ; Store a W value to a milliseconds counter 
 
 loop_1ms: 
         movlw   clks_1ms/5      ; Initialize internal loop counter to get 1 ms delay 
         movwf   intcnt          ; 
 
 int_loop: 
         clrwdt                  ; Waste a CPU cycle clearing a watchdog 
         nop                     ; Waste a CPU cycle doing nothing 
         decfsz  intcnt,f        ; Decrement INTCNT until zero 
         goto    int_loop        ; Must be 5 CPU cycles per single int_loop 
 
         decfsz  mscnt,f         ; Decrement MSCNT until zero 
         goto    loop_1ms        ; 
 
         return                  ; Done 
 ;-------------------------------------------------------------------------------------- 
 
         END                     ; End of program directive