Tip: Divide WREG by 10, PIC18

Hmmm, it does not work with 69... or am I missing something?

69*51=3519
PRODH=13
+50=63
/2=31

How about...

   addlw .1
   mullw .51
   bcf STATUS,C
   rrcf PRODH,W
 

Provided WREG is not 255 on entry

ORIGINAL: BitWise

How about...

   addlw .1
   mullw .51
   bcf STATUS,C
   rrcf PRODH,W
 

Provided WREG is not 255 on entry

Thanks for this neat DIV10-routine, done in 4 instructions! And thanks for Philippe for having the initial-idea. Of course, this will be added to the neat asm-tricks in the software-gallery!

Thanks,
Stefan

ORIGINAL: ppater

How about...

   addlw .1
   mullw .51
   rrcf PRODH,W
 

Provided WREG is not 255 on entry, there is no carry ...

Very nice. And how about:

   addlw .1
   btfsc STATUS,C
   addlw .255
   mullw .51
   rrcf PRODH,W
 

5 instructions then, but nothing provided...

EDIT: Corrected mistake, thanks Philippe!

ORIGINAL: ppater

ORIGINAL: Stefan Uhlemayr

ORIGINAL: ppater

How about...

   addlw .1
   mullw .51
   rrcf PRODH,W
 

Provided WREG is not 255 on entry, there is no carry ...

Very nice. And how about:

   addlw .1
   btfsc STATUS,C
   movlw .255
   mullw .51
   rrcf PRODH,W
 

5 instructions then, but nothing provided...

Does not work, movlw .255 does not reset carry...

So:

   addlw .1
   btfsc STATUS,C
   addlw .255
   mullw .51
   rrcf PRODH,W
 

ORIGINAL: Stefan Uhlemayr
Yes, this way works. Thanks for correction (I shouldn't write code without simulator [8|]).

Me too ...
Great piece of collaborative work!

ok  been away for a while and now we get it all working!!

good job

And now...
A full 8 bits binary to 3 digits routine based on previous code:
(provided bank selection is good)

 	ADDLW	.1		; adjust for 255?
 	BTFSS	STATUS, C
 	ADDLW	.255		; yes, set to 255
 	MULLW	.51		; "div by 5"
 	RRCF	PRODH, W		; div by 2
 	MOVWF	Tens		; save tens and ones
 	MULLW	.52		; "div by 5"
 	BCF	STATUS, C
 	RRCF	PRODH, W		; div by 2
 	MOVWF	Hunds		; save hunds
 	MOVF	Tens, W		; get back tens and ones
 	MOVWF	Ones		; save it in ones
 	MULLW	.51		; "div by 5"
 	RRCF	PRODH, W		; div by 2
 	MOVWF	Tens		; save tens
 	MULLW	.10		; restore power of 10
 	MOVF	PRODL, W		; get result
 	SUBWF	Ones, F		; adjust ones
 

Here's a 12 word "loop" version I came up with for a very resource limited 10F200 project which should work on 12/14/16 bit core devices (using lots more instruction cycles);

Regards, Mike

;******************************************************************
 ;                                                                 *
 ;  8 bit to 3 digit half-packed BCD, Mike McLaren, K8LH (Jan-09)  *
 ;                                                                 *
 ;   input: WREG, 0x00..0xFF, 0..255                               *
 ;  output: tens, 0x00..0x25, packed bcd                           *
 ;          ones, 0x00..0x09                                       *
 ;                                                                 *
 ;  12 words, 2 variables, 12/14/16 bit core devices               *
 ;                                                                 *
 Bin2Bcd
          clrf    tens            ;
          decf    tens,F          ; preset 'tens' to -1
 div10   movwf   ones            ;
          incf    tens,F          ; bump 'tens', 0x00..0x25
          movlw   6               ; using "packed bcd" format
          addwf   tens,W          ; bcd "digit carry"?
          skpndc                  ; no, skip, else
          movwf   tens            ; fix 'tens'
          movlw   10              ; ones = ones - 10
          subwf   ones,W          ; borrow?
          bc      div10           ; no, branch, else
 

And here's the companion routine for sending the 3-digit decimal number out your PutLCD or Put232 routine with leading zero suppression;

 ;
 ;  print number right justified and suppress leading zeros
 ;
 PutDec
          movlw   " "             ; seed leading zero 'mask'
          movwf   mask            ; mask = 0x20 = " " (space char)
          swapf   tens,W          ; get hundreds, 0..2
          call    PutDigit        ; print " " or "1".."2"
          movf    tens,W          ; get tens, 0..9
          call    PutDigit        ; print " " or "0".."9"
          movf    ones,W          ; get ones, 0..9
          goto    PutNumber       ; always print "0".."9"
 PutDigit
          andlw   0x0F            ;
          skpz                    ; zero? yes, skip, else
 PutNumber
          bsf     mask,4          ; mask = 0x30 = "0"
          iorwf   mask,W          ; wreg = " " or "0".."9"
          goto    Put232          ; Put232 or PutLCD
 
 

ORIGINAL: 1and0

How about...

     mullw   .205        ;W = W*205/2048
     rlncf   PRODH,w
     swapf   WREG
     andlw   0x1F

Tested with WREG = 0 to 255 in the simulator.

5 stars for this! I think, now we've got the perfect implementation of W DIV 10.

ORIGINAL: ppater

Great piece of collaborative work!

I can only second this!