cpu/xmega/ccp.S

Go to the documentation of this file.

#include <assembler.h>
#include <cpu/regs.h>

        /*
         * GNU and IAR use different calling conventions. Since this is
         * a very small and simple function to begin with, it's easier
         * to implement it twice than to deal with the differences
         * within a single implementation.
         *
         * Interrupts are disabled by hardware during the timed
         * sequence, so there's no need to save/restore interrupt state.
         */

        PUBLIC_FUNCTION(mmio_ccp_write8)

#if defined(__GNUC__)

        ST_CPUREG(r1, RAMPZ)            // Reset bits 23:16 of Z
        movw    r30, r24                // Load addr into Z
        ldi     r18, CCP_IOREG          // Load magic CCP value
        ST_CPUREG(r18, CCP)             // Start CCP handshake
        st      Z, r22                  // Write value to I/O register
        ret                             // Return to caller

#elif defined(__IAR_SYSTEMS_ASM__)

        ldi     r20, 0
        ST_CPUREG(r20, RAMPZ)           // Reset bits 23:16 of Z
# if defined(CONFIG_MEMORY_MODEL_TINY)
        mov     r31, r20                // Reset bits 8:15 of Z
        mov     r30, r16                // Load addr into Z
# else
        movw    r30, r16                // Load addr into Z
# endif
        ldi     r21, CCP_IOREG          // Load magic CCP value
        ST_CPUREG(r21, CCP)             // Start CCP handshake
# if defined(CONFIG_MEMORY_MODEL_TINY)
        st      Z, r17                  // Write value to I/O register
# elif defined(CONFIG_MEMORY_MODEL_SMALL)
        st      Z, r18                  // Write value to I/O register
# elif defined(CONFIG_MEMORY_MODEL_LARGE)
        st      Z, r19                  // Write value to I/O register
# else
#  error Unknown memory model in use, no idea how registers should be accessed
# endif
        ret                             // Return to caller

#else
# error Unknown assembler
#endif

        END_FUNC(mmio_ccp_write8)
        END_FILE()

---